中华钢结构论坛 China Structure Forum

标题: 请教ansys分析索膜结构找形 [打印本页]

作者: cons 时间: 2003-9-26 12:04 标题: 请教ansys分析索膜结构找形

刚刚学了一点ansys，希望找一个合适的算例来验证我的使用正确与否，不知道哪位大侠那里有算完的例题，我想借来参考一下，谢谢了
bow////

作者: lingdian 时间: 2003-10-14 19:31 标题: 回复：请教ansys分析索膜结构找形

Ansys计算索找行挺好用的，分析膜结构张拉膜结构不是很成熟，有一些问题需要解决的，充气膜结构也不是很理想，建议最好改用别的方法来算膜结构。

作者: shenly 时间: 2003-10-30 09:56 标题: 回复：请教ansys分析索膜结构找形

这里是前辈高手的一个例子，索网的找形与承载分析
沈士钊的悬索结构设计中的例子
/prep7
ET,1,LINK10
!找形时采用很小的弹性模量
R,1,0.001468,0.9,
MP,EX,1,0.60551e9
MP,NUXY,1,0.3
!定义节点
*do,i,1,5
*do,j,1,2*i-1
k=(i-1)*(i-1)+j
n,k,(j-i)*9.15,-36.6+(i-1)*9.15,0
*enddo
*enddo
*do,i,1,4
*do,j,1,2*i-1
k=(i-1)*(i-1)+j+25
n,k,(j-i)*9.15,36.6-(i-1)*9.15,0
*enddo
*enddo
!定义单元
*do,i,1,4
*do,j,1,2*i
k=i*i+j
e,k,k+1
*enddo
*enddo
*do,i,1,3
*do,j,1,2*i
k=i*i+j+25
e,k,k+1
*enddo
*enddo
*do,i,1,4
*do,j,1,2*i-1
k=(i-1)*(i-1)+j
e,k,k+2*i
*enddo
*enddo
*do,i,1,3
*do,j,1,2*i-1
k=(i-1)*(i-1)+j+25
e,k,k+2*i
*enddo
*enddo
*do,i,18,24
e,i,i+17
*enddo
!施加位移约束
d,1,ux,0
d,1,uy,0
d,1,uz,3.66
d,2,ux,0
d,2,uy,0
d,2,uz,1.83
d,4,ux,0
d,4,uy,0
d,4,uz,1.83
d,5,ux,0
d,5,uy,0
d,5,uz,0
d,9,ux,0
d,9,uy,0
d,9,uz,0
d,10,ux,0
d,10,uy,0
d,10,uz,-1.83
d,16,ux,0
d,16,uy,0
d,16,uz,-1.83
d,17,ux,0
d,17,uy,0
d,17,uz,-3.66
d,25,ux,0
d,25,uy,0
d,25,uz,-3.66
d,35,ux,0
d,35,uy,0
d,35,uz,-1.83
d,41,ux,0
d,41,uy,0
d,41,uz,-1.83
d,30,ux,0
d,30,uy,0
d,30,uz,0
d,34,ux,0
d,34,uy,0
d,34,uz,0
d,27,ux,0
d,27,uy,0
d,27,uz,1.83
d,29,ux,0
d,29,uy,0
d,29,uz,1.83
d,26,ux,0
d,26,uy,0
d,26,uz,3.66
!设定时间步
TIME,1
AUTOTS,0
NSUBST,20, , ,1
KBC,0
!输出每个子步的结果
OUTPR,BASIC,ALL,
OUTRES,ALL,ALL,
!设定大变形，应力刚化
NLGEOM,1
SSTIF,ON
FINISH
!求截
/SOLU
/STATUS,SOLU
SOLVE
FINISH
!后处理
/POST1
PRNSOL,DOF,
PRESOL,SMISC,1
PLESOL,SMISC,1
PLNSOL,U,X,0,1
finish
/PREP7
!更新几何形状
!a.rst为计算结果文件名，最后一个为目录
!这两个参数应根据你的计算情况定
UPGEOM,1,LAST,LAST,a,rst,E:\JZD\1\
!弹性模量恢复为真值
R,1,0.001468,0.0027248,
MP,EX,1,2.0e11
!重新施加位移约束
d,1,uz,0
d,2,uz,0
d,4,uz,0
d,5,uz,0
d,9,uz,0
d,10,uz,0
d,16,uz,0
d,17,uz,0
d,25,uz,0
d,35,uz,0
d,41,uz,0
d,30,uz,0
d,34,uz,0
d,27,uz,0
d,29,uz,0
d,26,uz,0
!求截
/SOLU
/STATUS,SOLU
SOLVE
FINISH
/POST1
!观察施加荷载之前结构的位移
!可见位移基本为零,预张力基本不变
PLNSOL,U,Z,0,1
PLESOL,SMISC,1
FINISH
!写荷载工况文件01
/PREP7
LSWRITE,01,
!施加节点荷载
*do,i,1,41
f,i,fz,-167445
*enddo
!设置第2荷载步
TIME,2
AUTOTS,0
NSUBST,20, , ,1
KBC,0
LSWRITE,02,
!求解
FINISH
/SOLU
LSSOLVE,1,2,1,
后处理
/POST26
!可以看到，该结果和书中结果一致
NSOL,2,21,U,Z,
PLVAR,2, , , , , , , , , ,
ESOL,3,33,1,F,Y,
PLVAR,3, , , , , , , , , ,

作者: TOMYI-2008 时间: 2004-4-20 21:09 标题: 回复：请教ansys分析索膜结构找形

多谢兄弟的例子！

作者: 丛林逐狼 时间: 2006-12-14 12:14 标题: 回复：请教ansys分析索膜结构找形

shenly 您好，谢谢你发的例子，我想问问，在索膜找形的时候是如何确定刚开始施加的位移约束的，因为刚刚开始做这个，是不是根据理知识论事先确定，还是根据变形大致的情况自己预估的一个值呢。

作者: yehaozhe 时间: 2007-6-20 10:29 标题: 求:接触悬挂的工程实例

我在做一个柔性结构的ANSYS分析,是关于接触悬挂的,
求一工程实例来验证我的分析的正确性.
具体的结构示意图见附件

作者: tsylxr 时间: 2007-6-20 11:28 标题: 回复：请教ansys分析索膜结构找形

可以查找电力铁路的接触网资料

欢迎光临中华钢结构论坛 China Structure Forum (http://okok.org/)