求关于索结构方面的ANSYS命令流，谢谢！

!EX8.21 悬索找形分析法求解
finish
/clear
/filname,ex821
/prep7
l0=120
area=7.016e-4
q0=65
qf=10000
h0=9000
xh=20.0
enum=60
istran=0.999
em=h0/(area*istran)*sqrt(l0*l0+xh*xh)/l0
et,1,link10
r,1,area,istran
mp,ex,1,em
mp,prxy,1,0.3
mp,dens,1,q0/area/(1-istran)
!在弦线位置创建模型，施加自重荷载
k,1
k,2,l0,-xh
l,1,2
lesize,all,,,enum
lmesh,all
d,node(0,0,0),all
d,node(l0,-xh,0),all
d,all,ux
acel,,1.0
finish

/solu
antype,0
nlgeom,on
sstif,on
nsubst,20
outres,all,all
solve
finish

/prep7
upgeom,1,last,last,ex821,rst
finish

!确定形状后，恢复真实材料特性等，求解初始状态
finish
/prep7
em=7.89e10
istran=1.0e-6
mp,ex,1,em
mp,dens,1,q0/area
r,1,area,istran
finish
/solu
ddele,all,all
d,node(0,0,0),all
d,node(l0,-xh,0),all
acel,,1.0
solve
finish

!如果该初始状态与所设置的H0不同，也可迭代几次
!求解外荷载作用下的内力和变形
/solu
f,node1,fy,-qf
nlgeom,on
nsubst,20
outres,all,all
solve
finish

!ex9.8 斜索的谐响应分析
finish
/clear
/prep7
a=0.006272
em=1.95e11
et,1,link1
mp,ex,1,em
mp,prxy,1,0.3
mp,dens,1,53/a
r,1,a
csys,1
k,1
k,2,110,38
l,1,2
lesize,all,,,55
lmesh,all
nrotat,all
d,1,all
d,2,uy,,,56
f,2,fx,4e6
/solu
antype,0
pstres,on
acel,,9.8
solve
finish
/solu
antype,harmic
hropt,full
pstres,on
acel,0,0,0
fdele,2,fx
ddel,3,uy,56
f,4,fy,1000
alphad,0.1
kbc,1
harfrq,0,7
nsubst,100
outres,all,all
solve
finish
/post26
nsol,2,29,u,y
nsol,3,29,u,x
plvar,2,3
/post1
set,list
set,1,18
pldisp,1

!ex8.23 两片索网找形与分析
finish
/clear
/filname,ex823
/prep7
netnx=40
netny=30
netsiz=2.2
f=10.0
a=0.00222
t0=1e5
istran=0.999
et,1,link10
r,1,a,istran
mp,ex,1,t0/(istran*a)
mp,prxy,1,0.3

xa=netnx*netsiz/2
xb=netny*netsiz/2
*do,i,1,netnx-1
xi=i*netsiz-xa
yi=sqrt(1-xi*xi/xa/xa)*xb
k,2*i-1,xi,-yi
k,2*i,xi,yi
l,2*i-1,2*i
*enddo
*get,kpmax,kp,,count
*do,i,1,netny-1
yi=i*netsiz-xb
xi=sqrt(1-yi*yi/xb/xb)*xa
k,kpmax+2*i-1,-xi,yi
k,kpmax+2*i,xi,yi
l,kpmax+2*i-1,kpmax+2*i
*enddo
nummrg,all
cm,kpcm,kp
lovlap,all
cmsel,s,kpcm
dk,all,all
allsel,all
!提升约束,抛物线形式
!y=-4*f/l/l*x*x+f
l0=netnx*netsiz
*do,i,1,netnx/2
xi=(i-1)*netsiz
dy=-4*f*xi*xi/l0/l0+f
dk,kp(xi,0,0),ux,,,,uy
dk,kp(xi,0,0),uz,dy
dk,kp(-xi,0,0),ux,,,,uy
dk,kp(-xi,0,0),uz,dy
*enddo
lesize,all,,,1
latt,1,1,1
lmesh,all
/solu
antype,0
nlgeom,on
sstif,on
nsubst,10
solve
finish
/prep7
upgeom,1,last,last,ex823,rst
*do,i,1,netnx/2
xi=(i-1)*netsiz
dk,kp(xi,0,0),uz
dk,kp(-xi,0,0),uz
*enddo
*do,i,1,5
finish
/solu
solve
finish
/prep7
upgeom,1,last,last,ex823,rst
*enddo
!索内力在99.3kN-102.1kN之间
mp,ex,1,1.9e11
r,1,a,t0/(1.9e11*a)
/solu
solve
finish
!索力几乎不变

!EX8.20 悬索直接迭代求解
finish
/clear
/filname,ex820
/prep7
l0=120
xh=20
area=7.016e-4
em=7.89e10
q0=65
qf=10000
h0=9000
err0=1/1000
enum=60
istran=1.0e-6
et,1,link10
r,1,area,istran
mp,ex,1,em
mp,prxy,1,0.3
mp,dens,1,q0/area
!在弦线位置创建模型，施加自重荷载
k,1
k,2,l0,-xh
l,1,2
lesize,all,,,enum
lmesh,all
d,node(0,0,0),all
d,node(l0,-xh,0),all
node1=nelem(enum/2,1)
node2=nelem(enum/2,2)
acel,,1.0
finish
!求解、更新、判别收敛条件
pass1=1
*dowhile,pass1
/solu
antype,0
nlgeom,on
sstif,on
nsubst,20
outres,all,all
solve
finish
/post1
set,last,last
*get,nfor,elem,enum/2,smisc,1
cosref=(nx(node2)-nx(node1))/distnd(node1,node2)
nfor=nfor*abs(cosref)
err1=abs(nfor-h0)/h0
finish
/prep7
*if,err1,lt,0.05,then
upgeom,0.1,last,last,ex820,rst
*else
upgeom,1,last,last,ex820,rst
*endif
finish
*if,err1,lt,err0,exit
*enddo
!获得初始状态的索长等
/post1
set,last,last
plesol,smisc,1
etable,epelt,lepel,1
s=0
ds=0
*do,i,1,enum
*get,eleng,elem,i,leng
*get,epel,elem,i,etab,epelt
s=s+eleng
ds=ds+eleng*epel
*enddo
s0=s-ds
!求解外荷载作用下的内力和变形
/solu
f,node1,fy,-qf
nlgeom,on
nsubst,20
outres,all,all
solve
finish