请帮我编写一个.lsp的命令，通过这个命令，然后框取要统计的线段（包括多段线），然后能够分别统计出这些线段的x向、y向的总长度和线段的总长度。

建议你有时间学习一下lsp，象这个程序其实不难的，直线能够取出端部坐标，自然很简单，多段线稍微复杂些，要取出它各个定义点，坐标差值的绝对值总和就是x向、y向的总长度，线段的总长度更简单了。
自己用自己编，这是最好的。因为自己知道重点在哪，程序不考虑普遍性就十分精简。而其他人编，就会考虑程序的普遍性，程序会很复杂。
当然，只是建议。

帮你编写了一个lsp：
(defun c:WW (/ ss i lenx leny len et na pta ptb x1 x2 y1 y2 ptlist)
  (setq ss (ssget '((0 . "LINE,LWPOLYLINE"))))
  (setq i 0 lenx 0 leny 0 len 0)
  (repeat (sslength ss)
    (setq et(entget(ssname ss i)))
    (setq na (cdr(assoc 0 et)))
    (cond ((= na "LINE")
           (progn
            (setq pta(cdr(assoc 10 et)))
            (setq x1(car pta) y1(cadr pta))         
            (setq ptb(cdr(assoc 11 et)))
            (setq x2(car ptb) y2(cadr ptb))
            (setq lenx(+ lenx(abs (- x1 x2))))
            (setq leny(+ leny(abs (- y1 y2))))
            (setq len(+ len(distance pta ptb)))
           )
          )
         ((= na "LWPOLYLINE")
          (progn
           (setq ptlist (mapcar 'cdr (vl-remove-if '(lambda(x)(/= (car x) 10)) et)))
           (repeat (1- (length ptlist))
             (setq pta (nth 0 ptlist) ptb (nth 1 ptlist))
             (setq x1(car pta) y1(cadr pta))
             (setq x2(car ptb) y2(cadr ptb))
             (setq lenx(+ lenx(abs (- x1 x2))))
             (setq leny(+ leny(abs (- y1 y2))))
             (setq len(+ len(distance pta ptb)))            
             (setq ptlist(cdr ptlist))
           )
          )
         )
     )
   (setq i (1+ i))
   )
   (princ(strcat "\nX向投影和:"(rtos lenx 2 2) ",""Y向投影和:"(rtos leny 2 2)",""总长为"(rtos len 2 2)"。"))
   (princ)
)

上传几个自己收集的直线长度统计的小工具，希望对大家有所帮助

常青藤软件可以做到，统计n多线段长度和